Initial commit

.config/fish/completions/fisher.fish

@@ -0,0 +1,7 @@
+complete -c fisher -x -l help -d "print usage help"
+complete -c fisher -x -l version -d "print fisher version"
+complete -c fisher -x -n "__fish_use_subcommand" -a install -d "install plugins"
+complete -c fisher -x -n "__fish_use_subcommand" -a update -d "update installed plugins"
+complete -c fisher -x -n "__fish_use_subcommand" -a remove -d "remove installed plugins"
+complete -c fisher -x -n "__fish_use_subcommand" -a list -d "list installed plugins matching <regex>"
+complete -c fisher -x -n "__fish_seen_subcommand_from update remove" -a "(fisher list)"

.config/fish/conf.d/gem_path.fish

@@ -0,0 +1 @@
+set PATH $PATH $HOME/.gem/ruby/2.6.0/bin

.config/fish/conf.d/go_path.fish

@@ -0,0 +1,2 @@
+set -x -U GOPATH $HOME/build/go
+set PATH $PATH $HOME/build/go/bin

.config/fish/conf.d/pip_path.fish

@@ -0,0 +1,2 @@
+set PATH $PATH $HOME/.local/bin
+set PATH $PATH $HOME/.cargo/bin

.config/fish/conf.d/purify.fish

@@ -0,0 +1,79 @@
+# name: purify
+# base on: theme-clearance (https://github.com/oh-my-fish/theme-clearance)
+
+# Set fish global colors
+set -l normal     fafafa
+set -l selection  3e4452
+set -l comment    5f5f87
+
+set -l red    ff6059
+set -l green  5fff87
+set -l blue   5fafff
+set -l yellow ffff87
+set -l pink   ff79c6
+set -l salmon ff875f
+
+set -g fish_color_autosuggestion $selection
+set -g fish_color_command        $green
+set -g fish_color_comment        $comment
+set -g fish_color_end            $salmon
+set -g fish_color_error          $red
+set -g fish_color_escape         $pink
+set -g fish_color_normal         $normal
+set -g fish_color_operator       $green
+set -g fish_color_param          $normal
+set -g fish_color_quote          $yellow
+set -g fish_color_redirection    $foreground
+set -g fish_color_search_match   --background=$selection
+set -g fish_color_selection      --background=$selection
+
+# Function to support git
+#function _git_branch_name
+#  echo (command git symbolic-ref HEAD 2> /dev/null | sed -e 's|^refs/heads/||')
+#end
+
+#function _git_is_dirty
+#  echo (command git status -s --ignore-submodules=dirty 2> /dev/null)
+#end
+
+#function fish_prompt
+#  set -l last_status $status
+
+  # Define required colors
+#  set -l cyan   (set_color 88fcfc)
+#  set -l pink   (set_color ff79c6)
+#  set -l red    (set_color ff6059)
+#  set -l blue   (set_color 5fafff)
+#  set -l green  (set_color 5fff87)
+#  set -l normal (set_color fafafa)
+
+#  set -l cwd $blue(pwd | sed "s:^$HOME:~:")
+
+  # Add a newline before new prompts
+#  echo -e ''
+
+  # Display [venvname] if in a virtualenv
+#  if set -q VIRTUAL_ENV
+#      echo -n -s (set_color -b blue black) '[' (basename "$VIRTUAL_ENV") ']' $normal ' '
+#  end
+
+  # Print pwd or full path
+#  echo -n -s $cwd $normal
+
+  # Show git branch and status
+ # if [ (_git_branch_name) ]
+ #   set -l git_branch (_git_branch_name)
+#
+#    if [ (_git_is_dirty) ]
+#      set git_info $cyan $git_branch $red " !"
+#    else
+#      set git_info $cyan $git_branch $green " √"
+#    end
+
+#    echo -n -s $cyan ' ⇢  ' $git_info
+#  end
+
+  # Terminate with a nice prompt char
+#  echo -e ''
+#  echo -e -n -s $pink '❯ '
+#end

.config/fish/conf.d/startx.fish

@@ -0,0 +1,6 @@
+# Start X at login
+if status --is-login
+	if test -z "$DISPLAY" -a $XDG_VTNR = 1
+		exec startx
+	end    
+end

.config/fish/config.fish

@@ -0,0 +1,3 @@
+if status is-interactive
+    # Commands to run in interactive sessions can go here
+end

.config/fish/fish_plugins

@@ -0,0 +1 @@
+jorgebucaran/fisher

.config/fish/fish_variables

@@ -0,0 +1,35 @@
+# This file contains fish universal variable definitions.
+# VERSION: 3.0
+SETUVAR --export --path GOPATH:/home/bredow/build/go
+SETUVAR __fish_initialized:3100
+SETUVAR _fisher_jorgebucaran_2F_fisher_files:/home/bredow/\x2econfig/fish/functions/fisher\x2efish\x1e/home/bredow/\x2econfig/fish/completions/fisher\x2efish
+SETUVAR _fisher_plugins:jorgebucaran/fisher
+SETUVAR fish_color_autosuggestion:555\x1ebrblack
+SETUVAR fish_color_cancel:\x2dr
+SETUVAR fish_color_command:005fd7
+SETUVAR fish_color_comment:990000
+SETUVAR fish_color_cwd:green
+SETUVAR fish_color_cwd_root:red
+SETUVAR fish_color_end:009900
+SETUVAR fish_color_error:ff0000
+SETUVAR fish_color_escape:00a6b2
+SETUVAR fish_color_history_current:\x2d\x2dbold
+SETUVAR fish_color_host:normal
+SETUVAR fish_color_host_remote:yellow
+SETUVAR fish_color_match:\x2d\x2dbackground\x3dbrblue
+SETUVAR fish_color_normal:normal
+SETUVAR fish_color_operator:00a6b2
+SETUVAR fish_color_param:00afff
+SETUVAR fish_color_quote:999900
+SETUVAR fish_color_redirection:00afff
+SETUVAR fish_color_search_match:bryellow\x1e\x2d\x2dbackground\x3dbrblack
+SETUVAR fish_color_selection:white\x1e\x2d\x2dbold\x1e\x2d\x2dbackground\x3dbrblack
+SETUVAR fish_color_status:red
+SETUVAR fish_color_user:brgreen
+SETUVAR fish_color_valid_path:\x2d\x2dunderline
+SETUVAR fish_greeting:Bienvenue\x20dans\x20fish\x2c\x20le\x20shell\x20amical\x20et\x20interactif\x0aType\x20\x60help\x60\x20for\x20instructions\x20on\x20how\x20to\x20use\x20fish
+SETUVAR fish_key_bindings:fish_vi_key_bindings
+SETUVAR fish_pager_color_completion:\x1d
+SETUVAR fish_pager_color_description:B3A06D\x1eyellow
+SETUVAR fish_pager_color_prefix:white\x1e\x2d\x2dbold\x1e\x2d\x2dunderline
+SETUVAR fish_pager_color_progress:brwhite\x1e\x2d\x2dbackground\x3dcyan

.config/fish/functions/dotfiles.fish

@@ -0,0 +1,4 @@
+# Defined in - @ line 1
+function dotfiles 
+	/usr/bin/git --git-dir=$HOME/.config/dotfiles/ --work-tree=$HOME $argv
+end

.config/fish/functions/fish_user_key_bindings.fish

@@ -0,0 +1,4 @@
+
+function fish_user_key_bindings
+  fish_vi_key_bindings
+end

.config/fish/functions/fisher.fish

@@ -0,0 +1,206 @@
+set -g fisher_version 4.1.0
+
+function fisher -a cmd -d "fish plugin manager"
+    set -q fisher_path || set -l fisher_path $__fish_config_dir
+    set -l fish_plugins $__fish_config_dir/fish_plugins
+
+    switch "$cmd"
+        case -v --version
+            echo "fisher, version $fisher_version"
+        case "" -h --help
+            echo "usage: fisher install <plugins...>  install plugins"
+            echo "       fisher remove  <plugins...>  remove installed plugins"
+            echo "       fisher update  <plugins...>  update installed plugins"
+            echo "       fisher update                update all installed plugins"
+            echo "       fisher list    [<regex>]     list installed plugins matching regex"
+            echo "options:"
+            echo "       -v or --version  print fisher version"
+            echo "       -h or --help     print this help message"
+        case ls list
+            string match --entire --regex -- "$argv[2]" $_fisher_plugins
+        case install update remove
+            isatty || read -laz stdin && set -a argv $stdin
+            set -l install_plugins
+            set -l update_plugins
+            set -l remove_plugins
+            set -l arg_plugins $argv[2..-1]
+            set -l old_plugins $_fisher_plugins
+            set -l new_plugins
+
+            if not set -q argv[2]
+                if test "$cmd" != update || test ! -e $fish_plugins
+                    echo "fisher: not enough arguments for command: \"$cmd\"" >&2 && return 1
+                end
+                set arg_plugins (string trim <$fish_plugins)
+            end
+
+            for plugin in $arg_plugins
+                test -e "$plugin" && set plugin (realpath $plugin)
+                contains -- "$plugin" $new_plugins || set -a new_plugins $plugin
+            end
+
+            if set -q argv[2]
+                for plugin in $new_plugins
+                    if contains -- "$plugin" $old_plugins
+                        if test "$cmd" = remove
+                            set -a remove_plugins $plugin
+                        else
+                            set -a update_plugins $plugin
+                        end
+                    else if test "$cmd" != install
+                        echo "fisher: plugin not installed: \"$plugin\"" >&2 && return 1
+                    else
+                        set -a install_plugins $plugin
+                    end
+                end
+            else
+                for plugin in $new_plugins
+                    if contains -- "$plugin" $old_plugins
+                        set -a update_plugins $plugin
+                    else
+                        set -a install_plugins $plugin
+                    end
+                end
+
+                for plugin in $old_plugins
+                    if not contains -- "$plugin" $new_plugins
+                        set -a remove_plugins $plugin
+                    end
+                end
+            end
+
+            set -l pid_list
+            set -l source_plugins
+            set -l fetch_plugins $update_plugins $install_plugins
+            echo -e "\x1b[1mfisher $cmd version $fisher_version\x1b[22m"
+
+            for plugin in $fetch_plugins
+                set -l source (command mktemp -d)
+                set -a source_plugins $source
+
+                command mkdir -p $source/{completions,conf.d,functions}
+
+                fish -c "
+                if test -e $plugin
+                    command cp -Rf $plugin/* $source
+                else 
+                    set temp (command mktemp -d)
+                    set name (string split \@ $plugin) || set name[2] HEAD
+                    set url https://codeload.github.com/\$name[1]/tar.gz/\$name[2]
+                    set -q fisher_user_api_token && set opts -u $fisher_user_api_token
+
+                    echo -e \"fetching \x1b[4m\$url\x1b[24m\"
+                    if command curl $opts -Ss -w \"\" \$url 2>&1 | command tar -xzf- -C \$temp 2>/dev/null
+                        command cp -Rf \$temp/*/* $source
+                    else
+                        echo fisher: invalid plugin name or host unavailable: \\\"$plugin\\\" >&2
+                        command rm -rf $source
+                    end
+                    command rm -rf \$temp
+                end
+
+                test ! -e $source && exit
+                command mv -f (string match --entire --regex -- \.fish\\\$ $source/*) $source/functions 2>/dev/null" &
+
+                set -a pid_list (jobs --last --pid)
+            end
+
+            wait $pid_list 2>/dev/null
+
+            for plugin in $fetch_plugins
+                if set -l source $source_plugins[(contains --index -- "$plugin" $fetch_plugins)] && test ! -e $source
+                    if set -l index (contains --index -- "$plugin" $install_plugins)
+                        set -e install_plugins[$index]
+                    else
+                        set -e update_plugins[(contains --index -- "$plugin" $update_plugins)]
+                    end
+                end
+            end
+
+            for plugin in $update_plugins $remove_plugins
+                if set -l index (contains --index -- "$plugin" $_fisher_plugins)
+                    set -l plugin_files_var _fisher_(string escape --style=var $plugin)_files
+
+                    if contains -- "$plugin" $remove_plugins && set --erase _fisher_plugins[$index]
+                        for file in (string match --entire --regex -- "conf\.d/" $$plugin_files_var)
+                            emit (string replace --all --regex -- '^.*/|\.fish$' "" $file)_uninstall
+                        end
+                        echo -es "removing \x1b[1m$plugin\x1b[22m" \n"         "$$plugin_files_var
+                    end
+
+                    command rm -rf $$plugin_files_var
+                    functions --erase (string match --entire --regex -- "functions/" $$plugin_files_var \
+                        | string replace --all --regex -- '^.*/|\.fish$' "")
+                    set --erase $plugin_files_var
+                end
+            end
+
+            if set -q update_plugins[1] || set -q install_plugins[1]
+                command mkdir -p $fisher_path/{functions,conf.d,completions}
+            end
+
+            for plugin in $update_plugins $install_plugins
+                set -l source $source_plugins[(contains --index -- "$plugin" $fetch_plugins)]
+                set -l files $source/{functions,conf.d,completions}/*
+                set -l plugin_files_var _fisher_(string escape --style=var $plugin)_files
+                set -q files[1] && set -U $plugin_files_var (string replace $source $fisher_path $files)
+
+                for file in (string replace -- $source "" $files)
+                    command cp -Rf $source/$file $fisher_path/$file
+                end
+
+                contains -- $plugin $_fisher_plugins || set -Ua _fisher_plugins $plugin
+                contains -- $plugin $install_plugins && set -l event "install" || set -l event "update"
+                echo -es "installing \x1b[1m$plugin\x1b[22m" \n"           "$$plugin_files_var
+
+                for file in (string match --entire --regex -- "[functions/|conf\.d/].*fish\$" $$plugin_files_var)
+                    source $file
+                    if string match --quiet --regex -- "conf\.d/" $file
+                        emit (string replace --all --regex -- '^.*/|\.fish$' "" $file)_$event
+                    end
+                end
+            end
+
+            command rm -rf $source_plugins
+            functions -q fish_prompt || source $__fish_data_dir/functions/fish_prompt.fish
+
+            set -q _fisher_plugins[1] || set -e _fisher_plugins
+            set -q _fisher_plugins && printf "%s\n" $_fisher_plugins >$fish_plugins || command rm -f $fish_plugins
+
+            set -l total (count $install_plugins) (count $update_plugins) (count $remove_plugins)
+            test "$total" != "0 0 0" && echo (string join ", " (
+                test $total[1] = 0 || echo "installed $total[1]") (
+                test $total[2] = 0 || echo "updated $total[2]") (
+                test $total[3] = 0 || echo "removed $total[3]")
+            ) "plugin/s"
+        case \*
+            echo "fisher: unknown flag or command: \"$cmd\" (see `fisher -h`)" >&2 && return 1
+    end
+end
+
+## Migrations ##
+if functions -q _fisher_self_update || test -e $__fish_config_dir/fishfile # 3.x
+    function _fisher_migrate
+        function _fisher_complete
+            fisher install jorgebucaran/fisher >/dev/null 2>/dev/null
+            functions --erase _fisher_complete
+        end
+        set -q XDG_DATA_HOME || set XDG_DATA_HOME ~/.local/share
+        set -q XDG_CACHE_HOME || set XDG_CACHE_HOME ~/.cache
+        set -q XDG_CONFIG_HOME || set XDG_CONFIG_HOME ~/.config
+        set -q fisher_path || set fisher_path $__fish_config_dir
+        test -e $__fish_config_dir/fishfile && command awk '/#|^gitlab|^ *$/ { next } $0' <$__fish_config_dir/fishfile >>$__fish_config_dir/fish_plugins
+        command rm -rf $__fish_config_dir/fishfile $fisher_path/{conf.d,completions}/fisher.fish {$XDG_DATA_HOME,$XDG_CACHE_HOME,$XDG_CONFIG_HOME}/fisher
+        functions --erase _fisher_migrate _fisher_copy_user_key_bindings _fisher_ls _fisher_fmt _fisher_self_update _fisher_self_uninstall _fisher_commit _fisher_parse _fisher_fetch _fisher_add _fisher_rm _fisher_jobs _fisher_now _fisher_help
+        fisher update
+    end
+    echo "upgrading to fisher $fisher_version -- learn more at" (set_color --bold --underline)"https://git.io/fisher-4"(set_color normal)
+    _fisher_migrate >/dev/null 2>/dev/null
+else if functions -q _fisher_list # 4.0
+    set -q XDG_DATA_HOME || set -l XDG_DATA_HOME ~/.local/share
+    test -e $XDG_DATA_HOME/fisher && command rm -rf $XDG_DATA_HOME/fisher
+    functions --erase _fisher_list _fisher_plugin_parse
+    echo -n "upgrading to fisher $fisher_version new in-memory state.."
+    fisher update >/dev/null 2>/dev/null
+    echo -ne "done\r\n"
+end

.config/fish/functions/vim.fish

@@ -0,0 +1,4 @@
+# Defined in - @ line 1
+function vim --description 'alias vim nvim'
+	nvim  $argv;
+end

.config/fish/functions/yt-360.fish

@@ -0,0 +1,4 @@
+# Defined in - @ line 1
+function yt-360 --description alias\ yt-360\ youtube-dl\ -f\ \'bestvideo\[height\<=360\]+bestaudio/best\[height\<=360\]\'
+	youtube-dl -f 'bestvideo[height<=360]+bestaudio/best[height<=360]' $argv;
+end

.config/fish/functions/yt-480.fish

@@ -0,0 +1,4 @@
+# Defined in - @ line 1
+function yt-480 --description alias\ yt-480\ youtube-dl\ -f\ \'bestvideo\[height\<=480\]+bestaudio/best\[height\<=480\]\'
+	youtube-dl -f 'bestvideo[height<=480]+bestaudio/best[height<=480]' $argv;
+end

.config/fish/functions/yt-audio.fish

@@ -0,0 +1,4 @@
+# Defined in - @ line 1
+function yt-audio --description 'alias yt-audio youtube-dl -i --extract-audio --audio-format mp3'
+	youtube-dl -i --extract-audio --audio-format mp3 $argv;
+end